|
5.5.1 創建TextStream對象的方法
有三個常用方法用于創建或打開一個文本文件并返回TextStram對象，如表5-13所示：
表5-13 創建TextStream對象的方法及說明
方 法
說 明
CreateTextFile
(filename,overwrite,unicode)
在磁盤上用指定的文件名filename創建一個新文本文件，并返回一個與該文件對應的TextStream對象。如果可選的overwrite參數設置為True，將覆蓋具有同樣路徑的同名文件。缺省的overwrite是False。如果可選的unicode參數設置為False，該文件的內容將存儲為Unicode格式。缺省的unicode是False
OpenTextFile
(filename,iomode,create,format)
打開或創建（如果不存在）一個名為filename的文件，并且返回與該文件對應的TextStream對象。filename參數可以包含絕對或相對路徑。iomode參數說明需要的訪問類型。容許值是ForReading(1)(缺省)、ForWriting(2)、ForAppending(8)。寫入或追加到一個不存在的文件時，如果create參數設置為True，將創建一個新文件。缺省的create是False。format參數說明了讀或寫文件時的數據格式。容許值是TristateFalse(0)(缺省)，說明用ASCII數據格式；TristateTrue(-1)說明用Unicode數據格式；TristateUseDefault(-2)說明數據使用系統缺省的格式
OpenAsTextStream
(iomode,format)
打開一個指定的文件并且返回一個TextStream對象，可用于對該文件的讀、寫或追加。iomode參數說明了需要的訪問類型。容許值是ForReading(1)(缺省)、ForWriting(2)、ForAppending(8)。Format參數說明了讀寫文件的數據格式。容許值是TristateFalse(0)(缺省)，說明用ASCII數據格式；TristateTrue(-1)說明用Unicode數據格式；TristateUseDefault(-2)說明使用系統缺省的格式
上面列出的方法在FileSystemObject、Folder和File對象中的實現有所不同。如表5-14所示：
表5-14 三個對象中包含的方法
方 法
FileSystemObject對象
Folder對象
File對象
CreateTextFile
有
有
有
OpenTextFile
有
無
無
OpenAsTextStream
無
無
有
因此，可以使用這些方法創建一個新的文本文件，或者打開一個已存在的文件。則可得到與該文件相應的一個TextStream對象，可以使用TextStream對象的屬性和方法操作文件。
1． 創建新的文本文件
可以用CreateTextFile方法創建新的文本文件，或覆蓋一個已存在的文件。返回的TextStream對象可用來讀寫文件。
首先創建一個FileSystemObject對象，用來創建TextStream對象。下面這個例子是用VBScript創建一個“普通的”（即非Unicode）名為MyFile.txt的文件，并覆蓋已存在的同名文件：
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set objTStream = objFSO.CreateTextFile("C:\TextFiles\MyFile.txt", True, False)
這同樣可用JScript實現:
var objFSO = Server.CreateObject('Scripting.FileSystemObject');
var objTStream = objFSO.CreateTextFile('C:\TextFiles\MyFile.txt', true, false);
一旦創建了該文件，就可以使用objTStream（它是對一個TextStream對象的引用）對文件進行操作。
2． 打開已存在的文本文件
OpenTextFile方法用于打開一個已有的文本文件。它返回一個TextStream對象，可用這個對象對文件讀或追加數據。
同樣，首先創建一個FileSystemObject對象，然后用其創建一個TextStream對象。下面的VBScript程序例子打開一個名為MyFile.txt的文件，準備讀出其內容：
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set objTStream = objFSO.OpenTextFile("C:\TextFiles\MyFile.txt", ForReading)
用JScript：
var objFSO = Server.CreateObject('Scripting.FileSystemObject');
var objTStream = objFSO.OpenTextFile('C:\TextFiles\MyFile.txt', ForReading);
為了寫入一個文件或創建一個不存在的文件，可以用以下代碼：
' In VBScript:
Set objTStream = objFSO.OpenTextFile("C:\TextFiles\MyFile.txt", ForWriting, True)
// In JScript:
var objTStream = objFSO.OpenTextFile('C:\TextFiles\MyFile.txt', ForWriting, true);
如果要打開一個已有的Unicode文件，準備對其追加數據，但是不創建不存在的文件，可以用：
' In VBScript:
Set objTStream = objFSO.OpenTextFile("C:\TextFiles\MyFile.txt", ForReading, _
False, TristateTrue)
// In JScript:
var objTStream = objFSO.OpenTextFile('C:\TextFiles\MyFile.txt', ForReading, _
fasle, TristateTrue);
3． 作為一個TextStream對象打開一個File對象
可用File對象的OpenAsTextStream方法打開與該對象相應的文件，并且返回一個能對該文件進行讀、寫和追加的TextStream對象。所以，給定一個File對象（這種情況下不是FileSystemObject對象）——objFileObject，可作為一個“普通的”（非Unicode）TextStream對象打開它，以供追加文件內容：
' In VBScript:
Set objTStream = objFileObject.OpenAsTextStream(ForAppending, False)
// In JScript:
var objTStream = objFileObject.OpenTextFile(ForAppending, false);
注意，使用這種方法不需要文件名，因為程序的執行通過引用File對象進行，并且沒有create參數，因為該文件必須已存在，如果想從一個新的空的文件開始，可以用：
' In VBScript:
Set objTStream = objFileObject.OpenAsTextStream(ForWriting)
// In JScript:
var objTStream = objFileObject.OpenTextFile(ForWriting);
如果想讀取該文件：
' In VBScript:
Set objTStream = objFileObject.OpenAsTextStream(ForReading)
// In JScript:
var objTStream = objFileObject.OpenTextFile(ForReading);
5.5.2 TextStream對象成員概要
表5-15和表5-16是TextStream對象的全部屬性和方法的列表。下面將簡短介紹各個重要的成員的細節。
1． TextStream對象的屬性
TextStream的屬性提供有關文件內文件指針當前位置的信息，如表5-15所示。注意，所有的屬性是只讀的。
表5-15 TextStream對象的屬性及說明
屬 性
說 明
AtEndOfLine
如果文件位置指針在文件中一行的末尾則返回True
AtEndOfStream
如果文件位置指針在文件的末尾則返回True
Column
從1開始返回文件中當前字符的列號
Line
從1開始返回文件中當前行的行號
AtEndOfLine和AtEndOfStream屬性僅對以iomode參數為ForReading的方式打開的文件可用，否則將會出錯。
2． TextStream對象的方法
TextStream對象的方法如表5-16所示：
表5-16 TextStream對象的方法及說明
方 法
說 明
Close()
關閉一個打開的文件
Read(numchars)
從文件中讀出numchars個字符
ReadAll()
作為單個字符串讀出整個文件
ReadLine()
作為一個字符串從文件中讀出一行（直到回車符和換行）
Skip(numchars)
當從文件讀出時忽略numchars個字符
SkipLine()
當從文件讀出時忽略下一行
Write(string)
向文件寫入字符串string
WriteLine(string)
向文件寫入字符串string（可選）和換行符
WriteBlankLines(n)
向文件寫入n個換行符
3． 寫文本文件
一旦使用CreateTextFile、OpenTextFile或OpenAsTextStream方法以及ForWriting或ForAppending參數，創建一個對應于某個文件的TextStream對象，可以用下面的VBScript程序寫文件和關閉文件：
' In VBScript:
objTStream.WriteLine "At last I can create files with VBScript!"
objTStream.WriteLine
objTStream.WriteLine "Here are three blank lines:"
objTStream.WriteBlankLines 3
objTStream.Write "... and this is "
objTStream.WriteLine "the last line."
objTStream.Close
或者用JScript：
// In JScript:
objTStream.WriteLine('At last I can create files with JScript! ');
objTStream.WriteLine();
objTStream.WriteLine('Here are three blank lines: ');
objTStream.WriteBlankLines(3);
objTStream.Write('... and this is ');
objTStream.WriteLine('the last line. ');
objTStream.Close();
4． 讀文本文件
一旦使用CreateTextFile、OpenTextFile或OpenAsTextStream方法以及ForReading參數，創建一個對應于某個文件的TextStream對象，可以用下面的VBScript程序讀文件和關閉文件：
' In VBScript:
'read one line at a time until the end of the file is reached
Do While Not objTStream.AtEndOfStream
'get the line number
intLineNum = objTStream.Line
'format it as a 4-character string with leading zeros
strLineNum = Right("000" & CStr(intLineNum), 4)
'get the text of the line from the file
strLineText = objTStream.ReadLine
Response.Write strLineNum & ": " & strLineText & "<BR>"
Loop
objTStream.Close
或用JScript：
// In JScript:
// read one line at a time until the end of the file is reached
while (! objTStream.AtEndOfStream) {
// get the line number
intLineNum = objTStream.Line;
// format and convert to a string
strLineNum = '000' + intLineNum.toString();
strLineNum = substr(strLineNum, strLineNum.length – 4, 4)
// get the text of the line from the file
strLineText = objTStream.ReadLine();
Response.Write(strLineNum + ': ' + strLineText + '<BR>');
}
objTStream.Close();
5.5.3 TextStream對象舉例
為了了解使用TextStream對象操作磨滅文件的幾種方式，本書提供了一個VBScript示例頁面，該頁使用了大量的上述的代碼。從示例的Chapter05主菜單頁，選擇鏈接“Working With the TextStream Object”打開show_textstream.asp頁面。
該頁顯示了存儲在磁盤上名為MyFile.txt的文件的文本內容。在<TEXTAREA>控件里顯示的文本內容允許進行編輯，并且下面有三個按鈕。三個按鈕的作用分別是用<TEXTAREA>控件的內容更新（即取代）最初的文本，在已有文件內容的后面添加文本，或用初始的缺省內容重寫文件，如圖5-15所示：
圖5-15 TextStream對象示例頁面
1． 讀取已存在的文本文件的內容
每次載入該頁面，將打開文本文件并將讀取的內容置入<TEXTAREA>控件。注意我們如何使用Server.MapPath方法得到文件MyFile.txt的絕對物理路徑，該文件與示例頁面在同一目錄下。下面的程序創建FileSystemObject實例：
<%
strTextFile = Server.MapPath("MyFile.txt")
'create an instance of a FileSytemObject object
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
…
與書中本部分的大多數其他示例一樣，該頁包含一個<FORM>段以保存該頁面的HTML控件。ACTION是當前頁面，因此窗體的內容送回到同一頁面。
每次載入該頁面，<TEXTAREA>控件用文本文件的當前內容填充：
…
<FORM ACTION="<% = Request.ServerVariables("SCRIPT_NAME") %>" METHOD="POST">
The contents of the disk file <B><% = strTextFile %></B> are:<P>
<TEXTAREA NAME="txtContent" ROWS="10" COLS="50" WRAP="PHYSICAL">
<%
'open the text file as a TextStream object
Set objTStream = objFSO.OpenTextFile(strTextFile, ForReading)
'read one line at a time until the end of the file is reached
Do While Not objTStream.AtEndOfStream
'get the line number
intLineNum = objTStream.Line
'format and convert to a string
strLineNum = Right("00" & CStr(intLineNum), 3)
'get the text of the line from the file
strLineText = objTStream.ReadLine
Response.Write strLineNum & ": " & strLineText & vbCrLf
Loop
objTStream.Close
%>
</TEXTAREA><P>
由上面程序可知道如何打開文本文件進行讀取，遍歷整個文件每次讀取一行（而不是作為一個字符串讀出整個文件）。這是因為要添加自己的行號，行號不屬于該文件的文本。對從該文件讀出的每行（讀之前），檢索并且格式化Line屬性并創建一個三位數字的行號。然后把行編號和文本行放置頁面的<TEXTAREA>控件內。
2． 更新文本文件的內容
當點擊頁面的Update按鈕時（一般是在編輯了<TEXTAREA>控件里的文本以后），將把<TEXTAREA>控件里的內容重新寫入到該文本文件內。為此，該頁有相應的一些ASP代碼，在創建HTML控件以前檢驗Request.Form集合，查看點擊的是哪一個按鈕（如果有的話），然后就重新載入該頁。
如果點擊Update按鈕，搜集<TEXTAREA>控件的內容作為一個字符串，分離這個字符串使之成為獨立文本選擇的數組，并且打開文本文件準備重寫其內容，然后遍歷剛剛創建的數組，按行號循環寫入該行的內容：
…
'look for a command sent from the FORM section buttons
If Len(Request.Form("cmdUpdate")) Then
'Get contents of TEXTAREA control
strNewText = Request.Form("txtContent")
'Split it into an array of lines at each carriage return
arrLines = Split(strNewText, vbCrLf)
'Open the text file for writing, which replaces all existing content
Set objTStream = objFSO.OpenTextFile(strTextFile, ForWriting)
For intLine = 0 To UBound(arrLines)
strThisLine = arrLines(intLine)
'Write out each line in turn as long as it’s got a line number
If Len(strThisLine) > 4 Then objTStream.WriteLine Mid(strThisLine, 6)
Next
objTStream.Close
End If
…
HTML<TEXTAREA>控件可在返回的Value中增加額外字符，這依賴于原始HTML頁內的內容格式和WRAP屬性的設置。特別是應在ASP腳本結束定界符“%>”后立即寫上</TEXTAREA>標記，以防止增加一個額外的回車符號。即使用：
%></TEXTAREA><p>
而不使用：
%>
</TEXTAREA><P>
3． 向文本文件追加內容
當點擊Append按鈕時，可對已有的文件追加內容，與修改該文件內容類似，如圖5-16所示。區別是打開該文件是為了追加而不是為了改寫文件。調用OpenTextFile方法時可增加額外參數，防止在指定的文件2不存在時創建新文件。
…
If Len(Request.Form("cmdAppend")) Then
'append contents of TEXTAREA to file
strNewText = Request.Form("txtContent")
arrLines = Split(strNewText, vbCrLf)
Set objTStream = objFSO.OpenTextFile(strTextFile, ForAppending, False)
For intLine = 0 To UBound(arrLines)
strThisLine = arrLines(intLine)
If Len(strThisLine) > 4 Then objTStream.WriteLine Mid(strThisLine, 6)
Next
objTStream.Close
End If
…
圖5-16 向文本文件追加內容時的示例頁面
4． 重寫缺省內容
最后，Restore按鈕用來將初始缺省內容簡單地重寫回文本文件。代碼與用TextStream的方法寫一個文本文件類似：
…
If Len(Request.Form("cmdDefault")) Then
'write out default contents to file
Set objTStream = objFSO.CreateTextFile(strTextFile, True, False)
objTStream.WriteLine "At last I can create files with VBScript!"
objTStream.WriteLine
objTStream.WriteLine "Here are three blank lines:"
objTStream.WriteBlankLines 3
objTStream.Write "... and this is "
objTStream.WriteLine "the last line."
objTStream.Close
End If
5.6 小結
本章講述了在ASP頁面中使用對象和組件的強大能力。首先討論對象和組件的一般特性，以及它們的類型。然后集中論述了如何在ASP（及客戶端）腳本代碼內創建對象實例。
在頁面上使用的許多對象可能都是“外部”組件，這些組件安裝在服務器上，獨立于ASP。本章所討論的對象，當ASP使用一種缺省的腳本語言（如VBScript或JScript）時，總是可用的。其實現是通過scrrun.dll文件里的腳本運行期庫完成的。
這些對象是指Dictonary對象、FileSystemObject對象和TextStream對象。
Dictionary對象為我們提供了存儲值的一種有效方式，可根據名字進行索引和訪問，而不是根據一個數字進行訪問。這是存儲名字/值對這樣的數據的理想方式。
FileSystemObject對象和TextStream對象相互之間聯系密切，可使用它們訪問服務器或網絡（映射）的磁盤驅動器的目錄。FileSystemObject對象提供對驅動器、文件夾（目錄）和文件的存取，并提供了用于對于獲得更多的信息或移動、復制、刪除它們的屬性及方法。
可以創建對應于系統內的任何文件的TextStream對象，并通過該對象對文件進行讀取和寫入。對于讀寫過程它作為文本文件操作，甚至可以處理Unicode格式的文件。對文件系統的導航和讀寫能力的結合允許對服務器文件系統進行極其復雜的控制。還可以在客戶端腳本代碼中使用對象（有一定限制）。
|
